Niquet.nl

Handige en eenvoudige manier om Windows Product Key te achterhalen (OEM installatie)

Stel nou dat je - om wat voor reden dan ook - je licentie key wilt achterhalen van je Windows installatie omdat deze niet te zien is op een stickertje van Microsoft aan de zijkant  van je PC, dan heb ik hier een hele makkelijke tip.

Natuurlijk zijn er gratis tools voor te vinden om dit te achterhalen maar met de korte edoch slimme truc die ik hieronder zal uitleggen hoef je NIETS te installeren. Mooi toch? šŸ™‚

  1. Stap 1: toets op je toetsenbord tegelijkertijd in: je Windows key + de letter 'R' (van 'Run')
  2. Een dialoogscherm met de titel  'Uitvoeren' komt in beeld met een invoervak.
  3. Tik hier in 'cmd' en klik vervolgens op OK / of druk op de 'Enter-toets'. Hiermee wordt de zgn. DOS-prompt geopend
  4. Plak de volgende tekst in deze DOS-prompt:   wmic path softwareLicensingService get OA3xOriginalProductKey
  5. Druk vervolgens op de ENTER-toets en voila ... de Windows Product Key wordt getoond

Alternatief

Mocht het bovenstaande niet het gewenste resultaat geven dan hier een alternatief. Ook nu hoef je niets te installeren.

Het enige wat je hoeft te doen is onderstaande code in een nieuw tekstbestand te plakken, op te slaan met een bepaalde naam+extensie en vervolgens deze script uit te voeren.


Option Explicit

Dim objshell,path,DigitalID, Result
Set objshell = CreateObject("WScript.Shell")
'Set registry key path
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"
'Registry key value
DigitalID = objshell.RegRead(Path & "DigitalProductId")
Dim ProductName,ProductID,ProductKey,ProductData
'Get ProductName, ProductID, ProductKey
ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName")
ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID")
ProductKey = "Installed Key: " & ConvertToKey(DigitalID)
ProductData = ProductName & vbNewLine & ProductID & vbNewLine & ProductKey
'Show messbox if save to a file
If vbYes = MsgBox(ProductData & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then
Save ProductData
End If

'Convert binary to chars
Function ConvertToKey(Key)
Const KeyOffset = 52
Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert
'Check if OS is Windows 8
isWin8 = (Key(66) \ 6) And 1
Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4)
i = 24
Maps = "BCDFGHJKMPQRTVWXY2346789"
Do
Current= 0
j = 14
Do
Current = Current* 256
Current = Key(j + KeyOffset) + Current
Key(j + KeyOffset) = (Current \ 24)
Current=Current Mod 24
j = j -1
Loop While j >= 0
i = i -1
KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput
Last = Current
Loop While i >= 0

If (isWin8 = 1) Then
keypart1 = Mid(KeyOutput, 2, Last)
insert = "N"
KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0)
If Last = 0 Then KeyOutput = insert & KeyOutput
End If

ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5)

End Function
'Save data to a file
Function Save(Data)
Dim fso, fName, txt,objshell,UserName
Set objshell = CreateObject("wscript.shell")
'Get current user name
UserName = objshell.ExpandEnvironmentStrings("%UserName%")
'Create a text file on desktop
fName = "C:\Users\" & UserName & "\Desktop\WindowsKeyInfo.txt"
Set fso = CreateObject("Scripting.FileSystemObject")
Set txt = fso.CreateTextFile(fName)
txt.Writeline Data
txt.Close
End Function

Werkwijze

  1. Selecteer bovenstaande tekst en druk op je toetsenbord op CTRL-C (kopiƫren)
  2. Start Windows Notepad
  3. Plak de geselecteerde tekst met CTRL-V in dit nieuwe document
  4. Sla dit document ergens op (bijv. op je bureaublad) onder bijvoorbeeld de naam "GetWindowsKey.vbs". De naam op zich is niet van belang, wel de extensie 'vbs' (dan weet Windows dat dit een script is).
  5. Sluit het document af en ga met je verkenner naar de locatie waar je dit bestand hebt opgeslagen.
  6. Dubbelklik op dit bestand
  7. Je krijgt vervolgens een dialoogscherm met hierin je Licentie code.

Voorbeeld:

Leave a Comment